Graybyt3 Was Here

Linux business121.web-hosting.com 4.18.0-513.11.1.lve.el8.x86_64 #1 SMP Thu Jan 18 16:21:02 UTC 2024 x86_64
LiteSpeed
192.64.117.91

File Name : ax_check_compile_flag.m4

# ===========================================================================
#  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
# ===========================================================================
#
# SYNOPSIS
#
#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
#
# DESCRIPTION
#
#   Check whether the given FLAG works with the current language's compiler
#   or gives an error.  (Warnings, however, are ignored)
#
#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
#   success/failure.
#
#   If EXTRA-FLAGS is defined, it is added to the current language's default
#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
#   force the compiler to issue an error when a bad flag is given.
#
#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
#
#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
#
# LICENSE
#
#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
#
#   Copying and distribution of this file, with or without modification, are
#   permitted in any medium without royalty provided the copyright notice
#   and this notice are preserved.  This file is offered as-is, without any
#   warranty.

#serial 6

AC_DEFUN([AX_CHECK_COMPILE_FLAG],
[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
  AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
    [AS_VAR_SET(CACHEVAR,[yes])],
    [AS_VAR_SET(CACHEVAR,[no])])
  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
AS_VAR_IF(CACHEVAR,yes,
  [m4_default([$2], :)],
  [m4_default([$3], :)])
AS_VAR_POPDEF([CACHEVAR])dnl
])dnl AX_CHECK_COMPILE_FLAGS

System Information
*ReClick For Close
File : BlackDragon /simple/function.php

Name	Type	Size	Owner/Group	Permission	Last Modified	Actions
.	dir	-	root/linksafe	0755	2024-11-20 07:40:00
..	dir	-	root/root	0755	2024-03-03 10:56:49
Makefile.global	text/x-makefile	6.95 KB	root/linksafe	0644	2024-10-21 05:11:42
ax_check_compile_flag.m4	text/x-m4	2.05 KB	root/linksafe	0644	2024-10-21 05:11:42
ax_gcc_func_attribute.m4	text/x-m4	8.22 KB	root/linksafe	0644	2024-10-21 05:11:42
config.guess	text/x-shellscript	48.19 KB	root/linksafe	0755	2024-10-21 05:11:42
config.sub	text/x-shellscript	34.45 KB	root/linksafe	0755	2024-10-21 05:11:42
gen_stub.php	text/plain	115.96 KB	root/linksafe	0644	2024-10-21 05:11:42
libtool.m4	text/x-m4	323.83 KB	root/linksafe	0644	2024-10-21 05:11:42
ltmain.sh	text/x-shellscript	316.55 KB	root/linksafe	0644	2024-10-21 05:11:42
php.m4	text/x-m4	71.22 KB	root/linksafe	0644	2024-10-21 05:11:42
php_cxx_compile_stdcxx.m4	text/x-c++	17.22 KB	root/linksafe	0644	2024-10-21 05:11:42
phpize.m4	text/x-m4	5.17 KB	root/linksafe	0644	2024-10-21 05:11:42
pkg.m4	text/x-m4	10.01 KB	root/linksafe	0644	2024-10-21 05:11:42
run-tests.php	text/x-c	139.07 KB	root/linksafe	0644	2024-10-21 05:11:42
shtool	text/x-shellscript	64.22 KB	root/linksafe	0755	2024-10-21 05:11:42